Just for fun, and for testing the newly-built KIN computer...
OF approximately 50 runs on my KIM-1, I was able to land the Lunar Excursion Module without
crashing it -- maybe twice...  it's goddamn difficult to land it !

  Lunar Lander -- A program for KIM / 6502  By JIM BUTTERFIELD

***** Hex Dump - Lunar Lander *****

0200 A2 0D BD CC 02 95 D5 CA 10 F8 A2 05 A0 01 F8 18
0210 B5 D5 75 D7 95 D5 CA 88 10 F6 B5 D8 10 02 A9 99
0220 75 D5 95 D5 CA 10 E5 A5 D5 10 0D A9 00 85 E2 A2
0230 02 95 D5 95 DB CA 10 F9 38 A5 E0 E5 DD 85 E0 A2
0240 01 B5 DE E9 00 95 DE CA 10 F7 B0 0C A9 00 A2 03
0250 95 DD CA 10 FB 20 BD 02 A5 DE A6 DF 09 F0 A4 E1
0260 F0 20 F0 9C F0 A4 A2 FE A0 5A 18 A5 D9 69 05 A5
0270 D8 69 00 B0 04 A2 AD A0 DE 98 A4 E2 F0 04 A5 D5
0280 A6 D6 85 FB 86 FA A5 D9 A6 D8 10 05 38 A9 00 E5
0290 D9 85 F9 A9 02 85 E3 D8 20 1F 1F 20 6A 1F C9 13
02A0 F0 C0 B0 03 20 AD 02 C6 E3 D0 ED F0 B7 C9 0A 90
02B0 05 49 0F 85 E1 60 AA A5 DD F0 FA 86 DD A5 DD 38
02C0 F8 E9 05 85 DC A9 00 E9 00 85 DB 60 45 01 00 99
02D0 81 00 99 97 02 08 00 00 01 01
(Red marks beginning and end of program code)

Description -
This program starts at 0200. When started, you will find
yourself at 4500 feet and falling. The thrust on your machine
is set to low; so you will pick up speed due to the force of
gravity.

You can look at your fuel at any time by pressing the
"F" button. Your fuel (initially 800 pounds) will be shown
in the first four digits of the KIM display.
The first two digits of the KIM display always show
your rate of descent or ascent. "A" restores altitude.
Set your thrust by pressing buttons 1 through 9.
Warning: button 0 turns you motor off, and it will not
reignite! A thrust of 1, minimum, burns very little fuel;
but gravity will be pulling your craft down faster and
faster. A thrust of 9, maximum, overcomes gravity
and reduces your rate of descent very sharply A thrust of 5
exactly counterbalances gravity; you will continue to descend
(or ascend) at a constant rate. If you run out of fuel,
your thrust controls will become inoperative.
A safe landing is considered to be one where you land
at a descent rate of 5 or less. After you land, your thrust
controls will be inoperative, since the motor is automatically
turned off; but you can still preff "F" to look at your fuel.
Pressing "GO" starts a new flight.

Suggestions for a safe flight:

(1) Conserve fuel at the beginning by pressing 1.
You begin to pick up speed downwards.

(2) When your rate of descent gets up to the 90's,
you're falling fast enough. Press 5 to steady the rate.

(3) When your altitude reaches about 1500 feet,
you'll need to slow down. Press 9 and slow down fast.

(4) When your rate of descent has dropped to 15 or 20,
steady the craft by pressing 5 or 6.
Now you're on your own.

; main routine - initialization
0200 A2 0D GO LDX #13 fourteen bytes
0202 BD CC 02 LP1 LDA INIT,X
0205 95 D5 STA ALT,X
0207 CA DEX
0208 10 F8 BPL LP1
; Update height and velocity
020A A2 05 CALC LDX #5
020C A0 01 RECAL LDY #1
020E F8 SED
020F 18 CLC
0210 B5 D5 DIGIT LDA ALT,X
0212 75 D7 ADC ALT+2,X add each digit
0214 95 D5 STA ALT,X
0216 CA DEX
0217 88 DEY
0218 10 F6 BPL RECAL next digit
021A B5 D8 LDA ALT+3,X hi-order .. zero ..
021C 10 02 BPL INCR .. or ..
021E A9 99 LDA #$99
0220 75 D5 INCR ADC ALT,X
0222 95 D5 STA ALT,X
0224 CA DEX
0225 10 E5 BPL RECAL do next addition
0227 A5 D5 LDA ALT
0229 10 0D BPL UP still flying?
022B A9 00 LDA #0 nope, turn off
022D 85 E2 STA DOWN
022F A2 02 LDX #2
0231 95 D5 DD STA ALT,X
0233 95 DB STA TH2,X
0235 CA DEX
0236 10 F9 BPL DD
0238 38 UP SEC update fuel
0239 A5 E0 LDA FUEL+2
023B E5 DD SBC THRUST
023D 85 E0 STA FUEL+2
023F A2 01 LDX #1 two more digits to go
0241 B5 DE LP2 LDA FUEL,X
0243 E9 00 SBC #0
0245 95 DE STA FUEL,X
0247 CA DEX
0248 10 F7 BPL LP2
024A B0 0C BCS TANK still got fuel?
024C A9 00 LDA #0 nope, kill motor
024E A2 03 LDX #3
0250 95 DD LP3 STA THRUST,X
0252 CA DEX
0253 10 FB BPL LP3
; show alt, fuel, or messages
0255 20 BD 02 JSR THHRUST
0258 A5 DE TANK LDA FUEL fuel into registers
025A A6 DF LDX FUEL+1
025C 09 F0 ORA #$F0 plus F flag
025E A4 E1 LDY MODE
0260 F0 20 BEQ ST
0262 F0 9C GOLINK BEQ GO
0264 F0 A4 CLINK BEQ CALC
0266 A2 FE LDX #$FE
0268 A0 5A LDY #$5A
026A 18 CLC
026B A5 D9 LDA VEL+1
026D 69 05 ADC #5
026F A5 D8 LDA VEL
0271 69 00 ADC #0
0273 B0 04 BCS GOOD
0275 A2 AD LDX #$AD
0277 A0 DE LDY #$DE
0279 98 GOOD TYA
027A A4 E2 LDY DOWN
027C F0 04 BEQ ST
027E A5 D5 LDA ALT
0280 A6 D6 LDX ALT+1
0282 85 FB ST STA POINTH
0284 86 FA STX PONTL
; show rate of ascent/descent as absolute
0286 A5 D9 LDA VEL+1
0288 A6 D8 LDX VEL up or down?
028A 10 05 BPL FLY .. up, we're OK
028C 38 SEC
028D A9 00 LDA #0
028F E5 D9 SBC VEL+1
0291 85 F9 FLY STA INH
0293 A9 02 LDA #2 loop twice thru display
0295 85 E3 STA DECK
0297 D8 FLITE CLD display & key test
0298 20 1F 1F JSR SCANDS light 'em up!
029B 20 6A 1F JSR GETKEY check keys
029E C9 13 CMP #$13 GO key?
02A0 F0 C0 BEQ GOLINK ...yes
02A2 B0 03 BCS NOKEY .. if no key
02A4 20 AD 02 JSR DOKEY
02A7 C6 E3 NOKEY DEC DECK
02A9 D0 ED BNE FLITE
02AB F0 B7 BEQ CLINK to CALC
; subroutine to test keys
02AD C9 0A DOKEY CMP #$0A test numeric
02AF 90 05 BCC NUMBER
02B1 49 0F EOR #$0F Fuel F gives 0 flag
02B3 85 E1 STA MODE
02B5 60 RETRN RTS
02B6 AA NUMBER TAX
02B7 A5 DD LDA THRUST test; is motor off?
02B9 F0 FA BEQ RETRN yes, ignore key
02BB 86 DD STA THRUST no, store thrust
; calculate accel as thrust minus 5
02BD A5 DD THRSET LDA THRUST
02BF 38 SEC
02C0 F8 SED
02C1 E9 05 SBC #5
02C3 85 DC STA TH2+1
02C5 A9 00 LDA #0
02C7 E9 00 SBC #0
02C9 85 DB STA TH2
02CB 60 RTS
; initial values
02CC 45 01 00 .BYTE $45,1,0 altitude
02CF 99 81 00 .BYTE $99,$81,0 rate of ascent
02D2 99 97 .BYTE $99,$97 acceleration
02D4 02 .BYTE 2 thrust
02D5 08 00 00 .BYTE 8,0,0 fuel
02D8 01 .BYTE 1 display mode
02D9 01 .BYTE 1 in flight/landed
; end
00D5 ALT *=*+3
00D8 VEL *=*+3
00DB TH2 *=*+2
00DD THRUST *=*+1
00DE FUEL *=*+1
00E1 MODE *=*+1
00E2 DOWN *=*+1
00E3 DECK *=*+1
; linkages to KIM monitor
SCANDS = $1F1F
GETKEY = $1F6A
POINTH = $FB
POINTL = $FA
INH = $F9


ACKNOWLEDGEMENTS: Ted Beach suggested the addition of the F flag when displaying fuel.
Chuck Eaton spotted the cause of an erratic bug in the original keyboard input
subroutine. Thanks to both.  Source:  users.telenet.be/kim1-6502/6502/fbok.html#p5

The above is the assembly language for the 6502 microprocessor which is used in the
KIM and in this KIN computer.  Just for fun, here is a link to a web page which lets you write
programs in AppleSoft BASIC.  Basic is what we used to analyze our Roulette data on the Apple II.